Is it possible to use string with dots as selector

[milosjost]

Hi,
if there's an object like

another: {
    example: "sure"
}

is there a way to access value of example field by using "another.example" string?

I've tried using something like this

#getValue: {
	X1="in": { values: {}, field: string}
	out: string

	_fields: strings.Split(X1.field, ".")
	_something: X1.values
	for f in _fields {
		_something: _something[f]
	}
	out: _something
}

but you can't change value in cue so assigning to _something throws an error (though in error message I do get wanted value :) )

[myitcv]

Something like this perhaps:

import "strings"

input: {
    another: {
        example: "sure"
    }
}

index: "another.example"

_splitIndex: strings.Split(index, ".")
_resolvedValues: [for i, v in _splitIndex { [if i==0 {input}, _resolvedValues[i-1]][0][_splitIndex[i]] }]

output: _resolvedValues[len(_resolvedValues)-1]

gives:

input: {
	another: {
		example: "sure"
	}
}
index:  "another.example"
output: "sure"

https://tip.cuelang.org/play/?id=1NrNflvLB8Z#cue@export@cue

[milosjost]

That works. Thanks!