No help file - no instructions given

[WSPvorno]

No instructions given as to how to correctly load the files nor how to initiate them.

For instance, NETLOAD within Civil 3D loads it but trying to run ConvexHull - nothing comes up!

A detailed help file for how to use this would be fantastic please, thank you!

[gileCAD]

These files (DLLs) are libraries containing classes and extension methods to be used in AutoCAD .NET plugins.

[WSPvorno]

As someone without .NET knowledge, how can I go about using these DLLs please?

[gileCAD]

You cannot use these libraries outside of the AutoCAD .NET API.
If you are more familiar with AutoLISP, you can use the following function, it returns the list of the convex hull points for the points list passed as argument.

;; Returns the convex hull points list (quick hull algorithm)
(defun quickhull (pts / area filter loop lst minX maxX)

  (defun area (p1 p2 p3)
    (- (* (- (car p2) (car p1)) (- (cadr p3) (cadr p1)))
       (* (- (cadr p2) (cadr p1)) (- (car p3) (car p1)))
    )
  )

  (defun filter	(p1 p2 pts outparam / ref a lst)
    (setq ref 0)
    (foreach p pts
      (and (minusp (setq a (area p1 p2 p)))
	   (setq lst (cons p lst))
	   (< a ref)
	   (setq ref a)
	   (set outparam p)
      )
    )
    lst
  )

  (defun loop (p1 p2 pts / l pt)
    (if	(setq l (filter p1 p2 pts 'pt))
      (append (loop p1 pt l) (loop pt p2 l))
      (list p2)
    )
  )

  (setq	lst  (mapcar 'car pts)
	minX (assoc (apply 'min lst) pts)
	maxX (assoc (apply 'max lst) pts)
  )
  (append (loop minX maxX pts) (loop maxX minX pts))
)