What to use for first argument of pkg.generate() when library target has 'name_prefix' set

[andy5995]

For example, in this PR for the libui project, I've used the library object, but I get the warnings when running ninja

WARNING: Library target 'ui' has 'name_prefix' set. Compilers may not find it from its '-lui' linker flag in the 'ui.pc' pkg-config file.
WARNING: Library target 'ui' has 'name_prefix' set. Compilers may not find it from its '-lui' linker flag in the 'ui-uninstalled.pc' pkg-config file.

What should I be using for the first argument of pkg.generate()?

In the meson.build for that project, the library is declared like this:

libui_libui = library('ui', libui_sources,
	dependencies: libui_deps,
	build_rpath: libui_rpath,
	install_rpath: libui_rpath,
	name_prefix: 'lib',		# always call it libui, even in Windows DLLs
	install: true,
	gnu_symbol_visibility: 'hidden',
	c_args: ['-Dlibui_EXPORTS'],
	cpp_args: ['-Dlibui_EXPORTS'],
	objc_args: ['-Dlibui_EXPORTS'],
	link_args: libui_libui_link_args,
	soversion: libui_soversion,
	darwin_versions: [])		# TODO

The .pc file is output as

prefix=/usr/local
libdir=${prefix}/lib
includedir=${prefix}/include

Name: ui
Description: a portable GUI library for C
Version: undefined
Requires.private: gtk+-3.0 >= 3.10.0
Libs: -L${libdir} -lui
Libs.private: -lm -ldl
Cflags: -I${includedir}

[eli-schwartz]

I guess meson isn't (currently?) clever enough to notice that the name_prefix is still the default value on Linux, so it emits the warning anyway. In theory, this could be something meson learns to do...

Something that should work either way is:

kwargs = {}
if host_machine.system() == 'windows'
        kwargs = {'name_prefix': 'lib'} # always call it libui, even in Windows DLLs
endif

libui_libui = library('ui', libui_sources,
	dependencies: libui_deps,
	build_rpath: libui_rpath,
	install_rpath: libui_rpath,
	install: true,
	gnu_symbol_visibility: 'hidden',
	c_args: ['-Dlibui_EXPORTS'],
	cpp_args: ['-Dlibui_EXPORTS'],
	objc_args: ['-Dlibui_EXPORTS'],
	link_args: libui_libui_link_args,
	soversion: libui_soversion,
	darwin_versions: [],		# TODO
        kwargs: kwargs)

Those kwargs will only fill out the name_prefix value on Windows, and I guess only warn on Windows. What does Windows do when GCC or clang see -lui? Do they detect libui.dll?

[andy5995]

Thanks @eli-schwartz . I'll wait for the project maintainer to follow up with me on the PR to discuss this further.

Those kwargs will only fill out the name_prefix value on Windows, and I guess only warn on Windows. What does Windows do when GCC or clang see -lui? Do they detect libui.dll?

I'm not familiar enough with the project to answer that.