fusion/pointers: add pointer arithmetic operators

Author: timotheecour

changelog.md

@@ -1,3 +1,3 @@
 ## additions and changes
 
-- Added module `pointers` containing `toUncheckedArray`
+- Added module `pointers` containing `toUncheckedArray` and pointer arithmetic operators and indexing

src/fusion/pointers.nim

@@ -15,3 +15,31 @@ proc toUncheckedArray*[T](a: ptr T): ptr UncheckedArray[T] {.inline.} =
     pa[0] += 5
     doAssert a[1] == 105
   cast[ptr UncheckedArray[T]](a)
+
+template `+`*[T](p: ptr T, off: int): ptr T =
+  runnableExamples:
+    var a = @[10, 11, 12]
+    let pa = a[0].addr
+    doAssert (pa + 1)[] == 11
+    doAssert pa[2] == 12
+    pa[1] = 2
+    doAssert a[1] == 2
+  type T = typeof(p[]) # pending https://github.com/nim-lang/Nim/issues/13527
+  cast[ptr T](cast[ByteAddress](p) +% off * sizeof(T))
+
+template `-`*[T](p: ptr T, off: int): ptr T =
+  type T = typeof(p[])
+  cast[ptr T](cast[ByteAddress](p) -% off * sizeof(T))
+
+template `[]`*[T](p: ptr T, off: int): T =
+  (p + off)[]
+
+template `[]=`*[T](p: ptr T, off: int, val: T) =
+  (p + off)[] = val
+
+proc `+=`*[T](p: var ptr T, off: int) {.inline.} =
+  # not a template to avoid double evaluation issues
+  p = p + off
+
+proc `-=`*[T](p: var ptr T, off: int) {.inline.} =
+  p = p - off

tests/tpointers.nim

@@ -0,0 +1,19 @@
+import fusion/pointers
+
+block:
+  var a = @[10, 11, 12]
+  let pa = a[0].addr
+  let pb = pa + 1
+  doAssert pb[] == 11
+  doAssert (pb - 1)[] == 10
+  pa[] = 100
+  doAssert a[0] == 100
+  doAssert pa[1] == 11
+
+  var pc = pa
+  pc += 1
+  doAssert pc[] == 11
+  doAssert pc[0] == 11
+  doAssert pc == pb
+  pc -= 1
+  doAssert pc == pa