Add audio callback example

Author: tjammer

examples/audio/audio_raw_stream.ml

@@ -0,0 +1,91 @@
+open Raylib
+
+let width = 800.
+let max_samples = 512
+let frequency = ref 440.0
+let audio_frequency = ref 440.0
+let data = Array.make max_samples 0.0
+let sine_idx = ref 0.0
+
+let audio_input_callback buf (frames : Unsigned.uint) =
+  audio_frequency := !frequency +. ((!audio_frequency -. !frequency) *. 0.95);
+
+  let incr = !audio_frequency /. 44100.0 in
+  let shortbuf = Ctypes.(coerce (ptr void) (ptr short) buf) in
+  let iframes = Unsigned.UInt.to_int frames in
+  let d = Ctypes.CArray.from_ptr shortbuf iframes in
+  for i = 0 to iframes - 1 do
+    Ctypes.CArray.set d i
+      (int_of_float (23000.0 *. sin (2.0 *. Float.pi *. !sine_idx)));
+    sine_idx := !sine_idx +. incr;
+    if Float.compare !sine_idx 1.0 > 0 then sine_idx := !sine_idx -. 1.0
+  done;
+  ()
+
+let setup () =
+  init_window (int_of_float width) 450
+    "raylib [audio] example - raw audio streaming";
+  init_audio_device ();
+  set_audio_stream_buffer_size_default 4096;
+  let stream = load_audio_stream 44100 16 1 in
+  Raylib_callbacks.set_audio_stream_callback stream audio_input_callback;
+  play_audio_stream stream;
+  set_target_fps 30;
+  (stream, 1.0)
+
+let rec run (stream, old_frequency) =
+  if window_should_close () then (
+    unload_audio_stream stream;
+    close_audio_device ();
+    close_window ())
+  else
+    let mouse_pos = get_mouse_position () in
+
+    if is_mouse_button_down MouseButton.Left then (
+      let fp = Vector2.y mouse_pos in
+      let pan = Vector2.x mouse_pos /. width in
+      set_audio_stream_pan stream pan;
+      frequency := 40.0 +. fp);
+
+    if !frequency <> old_frequency then (
+      let wavelength = 22050.0 /. !frequency |> int_of_float in
+      let wavelength =
+        if wavelength > max_samples / 2 then max_samples / 2
+        else if wavelength < 1 then 1
+        else wavelength
+      in
+
+      (* write sine wave *)
+      for i = 0 to (wavelength * 2) - 1 do
+        let value =
+          sin Float.(pi *. 2.0 *. of_int i /. of_int wavelength) *. 32000.0
+        in
+        Array.set data i value
+      done;
+      for j = wavelength * 2 to max_samples - 1 do
+        Array.set data j 0.0
+      done);
+
+    begin_drawing ();
+    clear_background Color.raywhite;
+    draw_text
+      (Format.sprintf "sine frequency: %i" (int_of_float !frequency))
+      (get_screen_width () - 220)
+      10 20 Color.red;
+    draw_text "click mouse button to change frequency or pan" 10 10 20
+      Color.darkgray;
+
+    for i = 0 to int_of_float width - 1 do
+      let y =
+        250.0
+        +. 50.0
+           *. Array.get data (i * max_samples / int_of_float width)
+           /. 32000.0
+      in
+      draw_pixel_v (Vector2.create (float_of_int i) y) Color.red
+    done;
+
+    end_drawing ();
+    run (stream, !frequency)
+
+let () = setup () |> run

examples/audio/dune

@@ -7,3 +7,8 @@
  (name audio_music_stream)
  (modules Audio_music_stream)
  (libraries raylib))
+
+(executable
+ (name audio_raw_stream)
+ (modules Audio_raw_stream)
+ (libraries raylib raylib-callbacks))

src/c/raygui/functions.ml

@@ -171,9 +171,8 @@ module Functions (F : Ctypes.FOREIGN) = struct
   (*  List View with extended parameters *)
   let _list_view_ex =
     foreign "GuiListViewEx"
-      (Raylib.Rectangle.t
-      @-> ptr (const string)
-      @-> int @-> ptr int @-> ptr int @-> int @-> returning int)
+      (Raylib.Rectangle.t @-> ptr string @-> int @-> ptr int @-> ptr int @-> int
+     @-> returning int)
 
   (*  Message Box control, displays a message *)
   let _message_box =

src/c/raylib_callbacks/functions.ml

@@ -5,7 +5,8 @@ module Functions (F : Ctypes.FOREIGN) = struct
   open Raylib_c.Types
 
   let audio_callback =
-    Foreign.funptr Ctypes.(ptr void @-> uint @-> returning void)
+    Foreign.funptr ~thread_registration:true ~runtime_lock:true
+      Ctypes.(ptr void @-> uint @-> returning void)
 
   let set_audio_stream_callback =
     foreign "SetAudioStreamCallback"

src/callbacks/dune

@@ -1,4 +1,4 @@
 (library
- (name callbacks)
+ (name raylib_callbacks)
  (public_name raylib-callbacks)
- (libraries raylib raylib_callbacks_c))
+ (libraries raylib raylib_callbacks_c ctypes-foreign))

src/callbacks/callbacks.ml src/callbacks/raylib_callbacks.mlsrc/callbacks/callbacks.ml renamed to src/callbacks/raylib_callbacks.ml

@@ -3,21 +3,26 @@
 type audio_callback = unit Ctypes.ptr -> Unsigned.uint -> unit
 
 val set_audio_stream_callback : Raylib.AudioStream.t -> audio_callback -> unit
-(** [set_audio_stream_callback stream callback] Audio thread callback to request new data*)
+(** [set_audio_stream_callback stream callback] Audio thread callback to request
+    new data*)
 
 val attach_audio_stream_processor :
   Raylib.AudioStream.t -> audio_callback -> unit
-(** [attach_audio_stream_processor stream processor] Attach audio stream processor to stream, receives the samples as 'float'*)
+(** [attach_audio_stream_processor stream processor] Attach audio stream
+    processor to stream, receives the samples as 'float'*)
 
 val detach_audio_stream_processor :
   Raylib.AudioStream.t -> audio_callback -> unit
-(** [detach_audio_stream_processor stream processor] Detach audio stream processor from stream*)
+(** [detach_audio_stream_processor stream processor] Detach audio stream
+    processor from stream*)
 
 val attach_audio_mixed_processor : audio_callback -> unit
-(** [attach_audio_mixed_processor processor] Attach audio stream processor to the entire audio pipeline, receives the samples as 'float'*)
+(** [attach_audio_mixed_processor processor] Attach audio stream processor to
+    the entire audio pipeline, receives the samples as 'float'*)
 
 val detach_audio_mixed_processor : audio_callback -> unit
-(** [detach_audio_mixed_processor processor] Detach audio stream processor from the entire audio pipeline*)
+(** [detach_audio_mixed_processor processor] Detach audio stream processor from
+    the entire audio pipeline*)
 
 (** File callbacks *)